home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 007 / as02.arc / TRIM.ASM < prev    next >
Assembly Source File  |  1985-08-28  |  12KB  |  332 lines
  1.         name    trim
  2.         page    55,132
  3.         title   'TRIM - excerpt lines of a file'
  4. ;
  5. ; TRIM --- excerpts selected columns from each line
  6. ;          of a file and writes them to the selected
  7. ;          output device or file.
  8. ;          
  9. ; A "filter" for MS-DOS or PC-DOS version 2 or higher,
  10. ; after the fashion of Unix.   Reads from the standard input
  11. ; (redirectable) and writes to the standard output (redirectable). 
  12. ; Error messages are directed to the standard error device.  
  13. ;
  14. ; TRIM can be (and usually would be) used in a pipe, e.g.
  15. ;
  16. ;    | TRIM 7,45 |
  17. ;
  18. ; transmits only the characters in columns 7 to 45 (inclusive)
  19. ; of each line.  A minus sign reverses the action, e.g.
  20. ;
  21. ;    | TRIM -7,45 | 
  22. ;
  23. ; transmits all characters except those in columns 7 to 45.
  24. ; 
  25. ; Special actions:
  26. ;
  27. ;    | TRIM 0  |        deletes trailing spaces from lines, and
  28. ;    | TRIM -0 |        also discards empty lines
  29. ; 
  30. ; By A. K. Head, 6 Duffryn Place, Melbourne, Australia 3142
  31. ; and Ray Duncan, Laboratory Microsystems Inc.
  32. ;
  33.  
  34. command equ     80h             ; buffer for command tail
  35. fcb1    equ     5ch             ; default file control block #1
  36. fcb2    equ     6ch             ; default file control block #2
  37.  
  38. buflen  equ     16384           ; buffer length, alter to taste
  39.  
  40. cr      equ     0dh             ; ASCII carriage return
  41. lf      equ     0ah             ; ASCII line feed
  42. ff      equ     0ch             ; ASCII form feed
  43. eof     equ     01ah            ; End-of-file marker
  44. tab     equ     09h             ; ASCII tab code
  45. blank   equ     20h             ; ASCII blank
  46.  
  47.                                 ; DOS 2.x pre-defined handles
  48. stdin   equ     0000            ; standard input file
  49. stdout  equ     0001            ; standard output file
  50. stderr  equ     0002            ; standard error file
  51. stdaux  equ     0003            ; standard auxilliary file
  52. stdprn  equ     0004            ; standard printer file
  53.  
  54.  
  55. cseg    segment para public 'CODE'
  56.  
  57.         assume  cs:cseg,ds:cseg
  58.  
  59.         org     100H            ; start .COM at 100H
  60.  
  61. start:    jmp     near ptr trim
  62.  
  63. param1  dw      0               ; command parameter #1
  64. param2  dw      0               ; command parameter #2
  65. sign    dw      0               ; nonzero if "-" in command
  66. count   dw      0               ; column count, current line
  67. topin   dw      0               ; chars in input buffer - 1 
  68. char    db      0               ; current character
  69.  
  70. trim    proc    far
  71.  
  72.         xor     si,si           ; initialize buffer pointers
  73.         xor     di,di
  74.         mov     bx,fcb1+1    ; addr of parsed parameter 1
  75.         call    getprm          ; convert it
  76.         cmp     ax,0
  77.         je      trunc        ; zero parameter, go truncate
  78.                 ; trailing blanks etc.
  79.         mov     param1,ax       ; save first parameter
  80.         mov     bx,fcb2+1    ; addr of parsed parameter 2
  81.     cmp    byte ptr [bx],blank ; is it present at all?
  82.     jne    trim0        ; yes, proceed
  83.     jmp    err3        ; no, exit
  84. trim0:    
  85.         call    getprm        ; convert it
  86.         mov     param2,ax       ; save 2nd parameter
  87.         cmp     ax,param1       ; is end column < start column?
  88.         jnb     trim1
  89.         jmp     err3        ; yes, exit with error message
  90.         
  91. trim1:  mov     count,0         ; starting a new line,
  92.                                 ; initialize column counter
  93.  
  94. trim2:  inc     count           ; count characters
  95.         call    cin                ; read a character
  96.     mov    al,char        ; is it carriage return?
  97.     and    al,07fh        ; (ignore high bit in case 
  98.     cmp    al,cr        ;  this is Wordstar file)
  99.         je      trim5        ; yes, found end of line
  100.         mov     ax,count        ; fetch current char count
  101.         cmp     sign,0          ; is this include or exclude call?
  102.         jne     trim4        ; jump, -, exclude range
  103.                                 ; proceed, +, include range
  104.     cmp     ax,param1       ; is column counter within 
  105.                                 ; desired range?
  106.         jb      trim2           ; no, discard this char.
  107.         cmp     ax,param2
  108.         ja      trim2           ; no, discard this char.
  109.  
  110. trim3:    call    cout               ; yes, use this character
  111.         jmp     trim2           ; get next char.
  112.  
  113. trim4:    cmp     ax,param1       ; is column counter outside
  114.                                 ; of excluded range?
  115.         jb      trim3        ; yes, use this character
  116.         cmp     ax,param2
  117.         ja      trim3        ; yes, use this character 
  118.         jmp     trim2           ; no, discard this character
  119.  
  120. trim5:                ; found end of line
  121.         call    cout               ; write carriage return
  122.         call    cin                ; read presumed line feed
  123.         call    cout               ; write line feed
  124.         jmp     trim1
  125.  
  126.  
  127. trunc:                ; come here if zero parameter
  128.                 ; to delete trailing blanks from
  129.                 ; all lines.  If - sign was in
  130.                 ; command parameter, also delete
  131.                 ; empty lines completely.
  132.  
  133. trunc1: mov     count,0         ; initialize column counter
  134.         xor     bp,bp           ; init line pointer
  135.  
  136. trunc2: call    cin                ; read a character
  137.     mov    al,char        ; is it carriage return
  138.     and    al,07fh        ; (ignore high bit in case
  139.         cmp     al,cr             ;  this is Wordstar file) 
  140.         je      trunc3            ; yes, go process end of line
  141.         mov     al,char        ; transfer char. to forming line
  142.         mov     byte ptr ds:[line+bp],al
  143.         inc     bp
  144.         cmp     char,blank      ; is character a space code?
  145.         je      trunc2          ; yes, get next char
  146.         mov     count,bp        ; no, update column count
  147.         jmp     trunc2          ; get next char.
  148.  
  149. trunc3:    xor     bp,bp           ; text string now in LINE
  150.         call    cin                ; discard line feed
  151.         cmp     count,0         ; was line empty?
  152.         jne     trunc4            ; no, go output it
  153.         cmp     sign,0        ; deleting empty lines?
  154.         jne     trunc1          ; yes, discard this one
  155.         jmp     trunc5        ; no, send cr-lf sequence
  156.  
  157. trunc4:                            ; now transfer LINE to BUFOUT
  158.         mov     al,byte ptr ds:[bp+line]
  159.         mov     char,al         ; get next char and
  160.         call    cout               ; send it to output
  161.         inc     bp
  162.         cmp     bp,count        ; entire line sent yet?
  163.         jb      trunc4           ; no, send another char
  164.         
  165. trunc5: mov     char,cr         ; send carriage return
  166.         call    cout
  167.         mov     char,lf         ; and line feed
  168.         call    cout           
  169.         jmp     trunc1
  170.  
  171. exit:   cmp     di,0            ; output buffer empty?
  172.         je      exit1           ; yes
  173.         call    outbuf          ; no, flush it
  174. exit1:  mov     ax,4c00h        ; exit with return code=0
  175.         int     21h             ; if no errors were encountered
  176.  
  177.  
  178. err:                ; print error message and exit.
  179.                 ; DS:DX = addr of message
  180.                 ; CX    = length of message
  181.                 ; AL    = return code
  182.     push    ax        ; save return code
  183.     mov    ah,40h        ; function 40 = write
  184.     mov    bx,stderr    ; handle for error output
  185.     int    21h
  186.     pop    ax        ; retrieve return code
  187.     mov    ah,4ch        ; function 4C = exit
  188.     int    21h
  189.  
  190. err1:    mov     dx,offset err1msg  ; print "output device error" 
  191.         mov     cx,err1len
  192.     mov    al,1        ; return code = 1
  193.     jmp    err
  194.  
  195. err2:    mov     dx,offset err2msg  ; print "disk is full".
  196.         mov     cx,err2len
  197.     mov    al,2        ; return code = 2
  198.     jmp    err
  199.  
  200. err3:    mov     dx,offset err3msg  ; print "bad parameter"
  201.         mov     cx,err3len
  202.     mov    al,3        ; return code = 3
  203.     jmp    err
  204.  
  205. err4:    mov     dx,offset err4msg  ; print "input device error"
  206.         mov     cx,err4len
  207.     mov    al,4        ; return code = 4
  208.     jmp    err
  209.  
  210.  
  211. trim    endp
  212.  
  213.  
  214. cout       proc    near            ; output contents of "char"
  215.                                 ; with autobuffering
  216.         mov     al,char
  217.         mov     byte ptr [di+bufout],al
  218.         inc     di
  219.         cmp     di,buflen       ; buffer full yet?
  220.         jb      cout1
  221.         call    outbuf          ; write buffer
  222. cout1:     ret                     ; back to caller
  223. cout       endp
  224.  
  225.  
  226. outbuf  proc    near            ; write buffer to std output
  227.         mov     ah,40h          ; function 40 = write
  228.         mov     bx,stdout       ; predefined handle 
  229.         mov     cx,di           ; number of characters
  230.         lea     dx,bufout       ; DS:DX = buffer addr
  231.         int     21h             ; request DOS service
  232.         jc      err1        ; jump, device write error
  233.         cmp     ax,di
  234.         jne     err2        ; jump, disk is full
  235.         xor     di,di           ; initialize output buff pointer
  236.         ret                     ; back to caller
  237. outbuf  endp
  238.  
  239.  
  240. cin    proc    near            ; input next char with buffering
  241.         inc     si              ; bump input buffer pointer
  242.         cmp     si,topin        ; buffer exhausted?
  243.         jbe     cin2        ; no, jump
  244.         mov     ah,3fh          ; yes, read some more data
  245.         mov     bx,stdin        ; predefined handle
  246.         mov     cx,buflen       ; max length to read
  247.         lea     dx,bufin        ; DS:DX = input buffer addr
  248.         int     21h             ; request DOS service
  249.         jc      err4        ; jump, input device error
  250.         cmp     ax,0            ; end of file?
  251.     jne    cin1
  252.     jmp    exit            ; yes, goto success exit point
  253. cin1:    dec     ax              ; save offset of top of data
  254.         mov     topin,ax
  255.         xor     si,si           ; zero input buffer pointer
  256. cin2:    mov     al,byte ptr [si+bufin]
  257.         mov     char,al         ; get next char 
  258.         ret
  259. cin    endp
  260.  
  261.  
  262. getprm  proc    near            ; convert numeric parameter to
  263.                                 ; binary and return it in AX
  264.         xor     ax,ax           ; initialize forming answer
  265.         mov     cl,[bx]         ; get first char
  266.         cmp     cl,'-'          ; is it minus sign?
  267.         jne     getp2        ; no, jump
  268.         inc     sign            ; yes, set flag and
  269. getp1:    inc     bx              ; bump command string pointer
  270.                 ; past the "-" sign
  271.         mov     cl,[bx]         ; get next char
  272. getp2:    cmp    cl,'0'        ; at least 1 legal digit?
  273.     jb    getp6        ; no, exit
  274.     cmp    cl,'9'        
  275.     ja    getp6        ; no, exit
  276.     jmp    getp4
  277. getp3:    inc    bx        ; advance through string
  278.     mov    cl,[bx]
  279.     cmp     cl,'0'          ; make sure legal digit 0-9
  280.         jb      getp5        ; not digit, jump
  281.         cmp     cl,'9'
  282.         ja      getp5        ; not digit, jump
  283.         mov     dl,10           ; previous answer * 10
  284.         mul     dl
  285. getp4:    sub     cl,'0'          ; add in the new digit
  286.         xor     ch,ch
  287.         add     ax,cx
  288.         cmp     ah,0            ; new answer > 255?
  289.         je      getp3        ; no, keep converting
  290.         jmp     err3        ; yes, illegal parameter, exit
  291. getp5:    cmp    byte ptr[bx],blank ; if not digit, must be blank
  292.     jne    getp6        ; exit, bad parameter
  293.     ret            ; back to caller
  294. getp6:    jmp    err3        ; ... since too far to reach
  295.                 ; direct with conditional branch
  296. getprm  endp
  297.  
  298.  
  299. err1msg    db      cr,lf
  300.         db      'trim: output device error'
  301.         db      cr,lf
  302. err1len equ     (this byte)-(offset err1msg) 
  303.  
  304. err2msg    db      cr,lf
  305.         db      'trim: disk is full.'
  306.         db      cr,lf
  307. err2len equ     (this byte)-(offset err2msg) 
  308.  
  309. err3msg    db      cr,lf
  310.         db      'trim: bad parameter'
  311.         db      cr,lf
  312. err3len equ     (this byte)-(offset err3msg) 
  313.  
  314. err4msg    db      cr,lf
  315.         db      'trim: input device error'
  316.         db      cr,lf
  317. err4len equ     (this byte)-(offset err4msg) 
  318.  
  319.  
  320. bufin   equ     this byte       ; data is read here
  321.                                 ; from the standard input
  322.  
  323. bufout  equ     bufin+buflen    ; data to be written to
  324.                                 ; standard output is built here
  325.  
  326. line    equ     bufout+buflen   ; temporary line buffer
  327.  
  328.  
  329. cseg    ends
  330.  
  331.         end     start
  332.